home *** CD-ROM | disk | FTP | other *** search
/ Compendium Deluxe 2 / LSD and 17bit Compendium Deluxe - Volume II.iso / a / prog / asmsrc / meltdown.lha / DEMO / DEMO.S < prev    next >
Encoding:
Text File  |  1988-07-19  |  16.1 KB  |  727 lines
  1. *****************************************************************************
  2.  
  3.                 ******************
  4.                 *    The Demo    *
  5.                 *      Code      *    
  6.                 *       By       *
  7.                 *     Slaine     *
  8.                 *     Arena!     *
  9.                 ******************
  10.  
  11. *****************************************************************************
  12.     Incdir    df1:
  13.     Include    source/Macro
  14. *****************************************************************************
  15.     Chip
  16. CopCrea    =    $70000
  17. *****************************************************************************
  18.     Pos
  19.     Kill
  20. *****************************************************************************
  21.     Lea    Custom,A5
  22. *****************************************************************************
  23.     Blitwait
  24. *****************************************************************************
  25.     Move.l    #$70000,D0
  26.     Move.w    #512*64+40,D1
  27.     Bsr    Clear
  28. *****************************************************************************
  29.     Move.l    #$00010001,Part                ; Start With Bobs
  30. *****************************************************************************
  31. MainLoop
  32.     Bsr    SelectPart
  33.     TstMice    MainLoop                ; Wait For Mouse
  34. *****************************************************************************
  35.     Heal
  36.     Clr.l    d0
  37.     Rts
  38. *****************************************************************************
  39. Clear
  40.     Move.l    D0,Bltdpth(a5)
  41.     Move.l    #0,Bltafwm(a5)
  42.     Move.w    #0,Bltdmod(a5)
  43.     Move.l    #$01000000,Bltcon0(a5)
  44.     Move.w    D1,Bltsize(a5)
  45.     Blitwait
  46.     Rts
  47. *****************************************************************************
  48. SelectPart
  49.     Cmp.w    #1,Part
  50.     Beq    BobLoop
  51.     Cmp.w    #2,Part
  52.     Beq    Doapear
  53.     Cmp.w    #3,Part
  54.     Beq    Wiggle
  55.     Rts
  56. *****************************************************************************
  57. Part    Dc.l    0
  58. PartToRn
  59.     Dc.w    2
  60. *****************************************************************************
  61. BobLoop
  62.     Cmp.b    #72,$dff006
  63.     Bne    BobLoop
  64.     Cmp.w    #1,Part+2
  65.     Beq    SetBobPar
  66.     Tst.l    BobDel
  67.     Beq    OutOfTheBobs
  68.     Eor.w    #$7e00,ScreenPtr+2
  69.     Eor.w    #$7e00,Cop1l+2
  70.     Eor.w    #$7e00,Cop2l+2
  71.     Eor.w    #$7e00,Cop3l+2
  72.     Eor.w    #$7e00,Cop4l+2
  73.     Bsr    ClearCopBobs
  74.     Bsr    DoBobs
  75.     Bsr    DoCop
  76.     Sub.l    #1,BobDel
  77.     Cmp.l    #99,BobDel
  78.     Bgt    LeaveBobs
  79.     Move.l    CopDst,A0
  80.     Move.l    #$01000200,(a0)
  81.     Sub.l    #88,CopDst
  82. LeaveBobs
  83.     Bsr    UpDate
  84.     Rts
  85. OutOfTheBobs
  86.     Move.w    PartToRn,Part
  87.     Move.w    #$0001,Part+2
  88.     Rts
  89. *****************************************************************************
  90. SetBobPar
  91.     Move.l    #Copper1,Cop1lch(a5)            ; Init Copper
  92.     Move.l    #300,BobDel
  93.     Move.l    #CopEnd-64-44,CopDst
  94.     Bsr    CreateCop1
  95.     Clr.w    Part+2
  96.     Rts
  97. *****************************************************************************
  98. BobDel    Dc.l    300
  99. CopDst    Dc.l    CopEnd-64
  100. *****************************************************************************
  101. ClearCopBobs
  102.     Blitwait                    
  103.     Move.l    #$01000000,Bltcon0(a5)        
  104.     Move.w    #$0000,Bltdmod(a5)        
  105.     Move.l    ScreenPtr,A1
  106.     Move.l    a1,Bltdpth(A5)            
  107.     Move.l    #-1,Bltafwm(a5)            
  108.     Move.w    #200*64+40,Bltsize(a5)        
  109.     Movem.l    a0-a6/d0-d7,-(a7)        
  110.     Movem.l    RegFiller(pc),a1-a6/d0-d7    
  111.     Move.l    ScreenPtr,A0
  112.     Add.l    #32000,A0            
  113.     Rept    286                
  114.     Movem.l    a1-a6/d0-d7,-(a0)        
  115.     Endr                    
  116.     Movem.l    (a7)+,a0-a6/d0-d7        
  117.     Rts
  118. RegFiller
  119.     Dcb.l    16,0
  120.     Rts
  121. *****************************************************************************
  122. DoBobs
  123.     Blitwait
  124.     Move.w    #32,Bltdmod(a5)
  125.     Move.w    #32,Bltcmod(a5)
  126.     Move.w    #-2,Bltamod(a5)
  127.     Move.w    #-2,Bltbmod(a5)
  128.     Move.w    #$ffff,Bltafwm(a5)
  129.     Move.w    #$0000,Bltalwm(a5)
  130.     Move.l    #BobsMsk,Bltapth(a5)
  131.     Move.l    #Bobs,Bltbpth(a5)
  132.     Move.w    #320*64+4,d6
  133.     Lea    BobForm1+4,A0
  134.     Lea    Shifts,A1
  135.     Lea    Xsin,A2
  136.     Lea    Bltcon0(a5),A3
  137.     Lea    Bltcpth(a5),A4
  138.     Lea    Bltsize(a5),A6
  139.     Lea    Bltdpth(a5),a5
  140.     Move.l    ScreenPtr,d7
  141.     Move.l    #$200,d2
  142.     Rept    5    
  143.     Move.l    d7,d1
  144.     Move.w    (a0)+,D0                ; X
  145.     Move.w    (a2,d0),d0
  146.     Add.w    (a1,d0),d1
  147.     Move.l    2(a1,d0),(A3)
  148.     Move.w    (a0)+,D0                ; Y
  149.     Add.w    D2,D0
  150.     Add.w    (A2,d0),d1                ; Add y
  151.     Move.l    d1,(a4)
  152.     Move.l    d1,(a5)
  153.     Move.w    d6,(a6)
  154.     Endr
  155.     Lea    Custom,a5
  156.     Rts
  157. *****************************************************************************
  158. UpDate
  159.     Lea    BobForm1,A0
  160.     Move.l    (a0)+,d7
  161.     Move.l    #$01fe01fe,D6
  162.     Rept    5
  163.     Add.l    d7,(a0)
  164.     And.l    d6,(a0)+
  165.     Endr    
  166.     Rts
  167. *****************************************************************************
  168.     Include    Demo/Shifts
  169. *****************************************************************************
  170. CreateCop1
  171.     Lea    BobCopStart,A0
  172.     Move.l    #200-1,D7
  173.     Move.l    #$48ddfffe,D0
  174. CopLoop1
  175.     Move.l    D0,(a0)+
  176.     Move.w    #Color10,(a0)+
  177.     Clr.w    (a0)+
  178.     Move.w    #Color09,(a0)+
  179.     Clr.w    (a0)+
  180.     Move.w    #Color08,(a0)+
  181.     Clr.w    (a0)+
  182.     Move.w    #Color07,(a0)+
  183.     Clr.w    (a0)+
  184.     Move.w    #Color06,(a0)+
  185.     Clr.w    (a0)+
  186.     Move.w    #Color05,(a0)+
  187.     Clr.w    (a0)+
  188.     Move.w    #Color04,(a0)+
  189.     Clr.w    (a0)+
  190.     Move.w    #Color03,(a0)+
  191.     Clr.w    (a0)+
  192.     Move.w    #Color02,(a0)+
  193.     Clr.w    (a0)+
  194.     Move.w    #Color01,(a0)+
  195.     Clr.w    (a0)+
  196.     Add.l    #$01000000,d0
  197.     Dbf    D7,CopLoop1
  198.     Move.l    #$1009fffe,(a0)+
  199.     Move.l    #$0180000f,(a0)+
  200.     Move.l    #$01000200,(a0)+
  201.     Move.l    #$1109fffe,(a0)+
  202.     Move.l    #$01800000,(a0)+
  203.     Rts
  204. *****************************************************************************
  205. DoCop
  206.     Blitwait    
  207.     Move.l    #Col1,Bltapth(a5)
  208.     Move.l    #$09f00000,Bltcon0(a5)
  209.     Move.l    #-1,Bltafwm(A5)
  210.     Move.w    #0,Bltamod(A5)
  211.     Move.w    #42,Bltdmod(A5)
  212.     Move.w    #72*64+1,D3
  213.     Move.l    #BobCopStart+6+(0*44),A2
  214.     Lea    BobForm1+4,a0
  215.     Lea    YCopSin,a1
  216.     Move.l    #4,D1
  217.     Rept    5
  218.     Move.w    2(A0),d0
  219.     Move.w    (a1,d0),d0
  220.     Add.w    d0,a2
  221.     Move.l    A2,Bltdpth(a5)
  222.     Move.w    d3,Bltsize(a5)
  223.     Sub.w    d0,a2
  224.     Add.w    D1,A2
  225.     Move.w    2(A0),d0
  226.     Move.w    (a1,d0),d0
  227.     Add.w    d0,a2
  228.     Move.l    A2,Bltdpth(a5)
  229.     Move.w    d3,Bltsize(a5)
  230.     Sub.w    d0,a2
  231.     Add.w    D1,A2
  232.     Add.w    D1,A0
  233.     Endr
  234.     Rts
  235. *****************************************************************************
  236.     Include    Demo/BobCols
  237. *****************************************************************************
  238. Doapear
  239.     Pos
  240.     Cmp.w    #$0001,Part+2
  241.     Beq    SetApearPar    
  242.     Bsr    BlitOn
  243.     Rts
  244. SetApearPar    
  245.     Clr.w    Part+2
  246.     Blitwait
  247.     Move.l    #$70000,Bltdpth(a5)
  248.     Move.l    #-1,Bltafwm(a5)
  249.     Move.w    #0,Bltdmod(a5)
  250.     Move.l    #$01000000,Bltcon0(a5)
  251.     Move.w    #256*64+20,Bltsize(a5)
  252.     Blitwait
  253.     Move.l    #$73000,Bltdpth(a5)
  254.     Move.w    #256*64+20,Bltsize(a5)
  255.     Blitwait
  256.     Move.l    #Copper2,Cop1lch(a5)
  257.     Bsr    PrintPage
  258.     Clr.l    Xpos
  259.     Clr.l    Ypos
  260.     Move.w    #100,Del1
  261.     Rts
  262. *****************************************************************************
  263. Del    dc.w    0
  264. Del1    Dc.w    0
  265. *****************************************************************************
  266. BlitOn
  267.     Tst.w    Del
  268.     Beq    shaba
  269.     Sub.w    #1,Del
  270.     Rts
  271. shaba
  272.     Cmp.l    #$2080,YPos
  273.     Beq    FadeDown
  274.     Move.w    #2,Del
  275.     Move.l    #$0dc00000,Bltcon0(a5)
  276.     Move.l    #-1,Bltafwm(a5)
  277.     Move.w    #38,Bltdmod(a5)
  278.     Move.w    #38,Bltamod(a5)
  279.     Move.w    #00,Bltbmod(a5)
  280.     Move.l    #Apear1,A0
  281.     Move.l    a0,Bltbpth(a5)
  282.     Lea    $70000-(16*40),a0        ; Src
  283.     Lea    $73000-(16*40),A1        ; Dst
  284.     Move.l    #9-1,d7                ; Number Of Chars
  285.     Move.l    XPos,d0                ; X
  286.     Move.l    Ypos,d1                ; Y
  287. Apear
  288.     Add.w    D0,A0
  289.     Add.w    D1,A0
  290.     Add.w    D0,A1
  291.     Add.w    D1,A1
  292.     Move.l    a0,Bltapth(a5)
  293.     Move.l    a1,Bltdpth(a5)
  294.     Move.w    #16*64+1,Bltsize(a5)
  295.     Sub.w    D0,A0
  296.     Sub.w    D1,A0
  297.     Sub.w    D0,A1
  298.     Sub.w    D1,A1
  299.     Add.w    #2,D0
  300.     Cmp.w    #40,D0
  301.     Blt    Leavex
  302.     Clr.w    D0
  303.     Add.w    #16*40,D1
  304. Leavex
  305.     Dbf    d7,Apear
  306.     Add.l    #2,Xpos
  307.     Cmp.l    #40,Xpos
  308.     Blt    Shaga
  309.     Clr.l    Xpos
  310.     Add.l    #16*40,Ypos
  311. Shaga
  312.     Rts
  313. *****************************************************************************
  314. PrintPage
  315.     Move.l    #$09f00000,Bltcon0(a5)
  316.     Move.l    #-1,Bltafwm(a5)
  317.     Move.w    #38,Bltdmod(a5)
  318.     Move.w    #38,Bltamod(a5)
  319.     Move.l    pagePtr,A0
  320.     Move.l    #$70000,D1
  321.     Move.l    #12-1,D6
  322. Loop1
  323.     Move.l    #20-1,D7
  324. Loop2
  325.     Clr.l    D0
  326.     Clr.l    D2
  327.     Move.b    (a0)+,D0
  328.     Sub.b    #32,d0
  329.     Divu    #20,d0
  330.     Move.w    d0,d2
  331.     Mulu    #40*16,d2
  332.     Swap    d0
  333.     Add.w    d0,d0
  334.     Add.w    d0,d2
  335.     Add.l    #Font,D2
  336.     Blitwait
  337.     Move.l    D2,Bltapth(A5)
  338.     Move.l    D1,Bltdpth(A5)
  339.     Move.w    #16*64+1,Bltsize(a5)
  340.     Add.w    #2,D1
  341.     Dbf    D7,Loop2
  342.     Add.w    #(16*40)-40,d1
  343.     Dbf    D6,Loop1
  344.     Rts
  345. *****************************************************************************
  346. FadeDown
  347.     Cmp.w    #0,Del1
  348.     Beq.s    GoOn
  349.     Sub.w    #1,Del1
  350.     Rts
  351. GoOn    
  352.     Cmp.w    #$002,FadeDis+6
  353.     Beq.s    VarSkip1
  354.     Sub.w    #$111,FadeDis+6
  355. VarSkip1    
  356.     Cmp.w    #$002,FadeDis+10
  357.     Beq.s    VarSkip2
  358.     Sub.w    #$111,FadeDis+10
  359. VarSkip2
  360.     Sub.w    #$111,FadeDis+2
  361.     Cmp.w    #$002,FadeDis+2
  362.     Beq.s    FadeFin
  363.     Rts
  364. *****************************************************************************
  365. FadeFin
  366.     Move.w    #$ddf,FadeDis+2
  367.     Move.w    #$446,FadeDis+6
  368.     Move.w    #$88a,FadeDis+10
  369.     Move.l    PagePnt,A0
  370.     Move.l    (a0)+,D0
  371.     Cmp.l    #-1,D0
  372.     Bne.s    Pageon
  373.     Move.l    #PageFile,A0
  374.     Move.l    (a0)+,D0
  375. Pageon
  376.     Move.l    A0,PagePnt
  377.     Swap    D0
  378.     Cmp.w    #$ffff,D0
  379.     Bne.s    GoDoText
  380.     Swap    D0
  381.     Move.w    D0,Part
  382.     Move.w    #$0001,Part+2
  383.     Move.l    (a0)+,d0
  384.     Move.l    A0,PagePnt
  385.     Move.l    D0,PagePtr
  386.     Rts
  387. GoDoText
  388.     Swap    D0
  389.     Move.l    D0,PagePtr
  390.     Bsr    SetApearPar
  391.     Rts
  392. *****************************************************************************
  393. PagePtr
  394.     Dc.l    Page1
  395. *****************************************************************************
  396. PagePnt
  397.     Dc.l    PageFile
  398. PageFile
  399.     Dc.l    Page2,Page3,Page4
  400.     Dc.w    $ffff,3
  401.     Dc.l    Page1,-1
  402. *****************************************************************************
  403. Page1
  404.     Dc.b    "                    "    
  405.     Dc.b    "                    "    
  406.     Dc.b    "                    "    
  407.     Dc.b    "                    "    
  408.     Dc.b    "      PRESENT!      "    
  409.     Dc.b    "       A COOL       "    
  410.     Dc.b    "      NEW DEMO      "    
  411.     Dc.b    "       CALLED       "    
  412.     Dc.b    "                    "    
  413.     Dc.b    "                    "    
  414.     Dc.b    "                    "    
  415.     Dc.b    "                    "    
  416. Page2
  417.     Dc.b    "                    "    
  418.     Dc.b    "                    "    
  419.     Dc.b    "--------------------"
  420.     Dc.b    "***  *  ***  *  *   "
  421.     Dc.b    " *  * *  *  * * *   "
  422.     Dc.b    " *  * *  *  *** *   "
  423.     Dc.b    " *   *   *  * *  ** "
  424.     Dc.b    "--------------------"
  425.     Dc.b    "      CONTRAST      "
  426.     Dc.b    "--------------------"
  427.     Dc.b    "                    "    
  428.     Dc.b    "                    "    
  429. Page3
  430.     Dc.b    "                    "    
  431.     Dc.b    "       CREDITS      "    
  432.     Dc.b    "                    "    
  433.     Dc.b    "                    "    
  434.     Dc.b    "                    "    
  435.     Dc.b    "     CODE:SLAINE    "    
  436.     Dc.b    "      GFX:EFFEX     "    
  437.     Dc.b    "   MUSIC:NONE YET   "    
  438.     Dc.b    "                    "    
  439.     Dc.b    "                    "    
  440.     Dc.b    "                    "    
  441.     Dc.b    "                    "    
  442.  
  443. Page4
  444.     Dc.b    "                    "
  445.     Dc.b    "                    "
  446.     Dc.b    "                    "
  447.     Dc.b    "1 PIXEL COPPERS SEEM"
  448.     Dc.b    " TO BE THE IN THING "
  449.     Dc.b    " JUST BECAUSE THEY! "
  450.     Dc.b    " ARE SO EASY TO DO! "
  451.     Dc.b    "CHECK MY 10 MINS OFF"
  452.     Dc.b    "    CODE OUT NOW    "
  453.     Dc.b    "                    "
  454.     Dc.b    "                    "
  455.     Dc.b    "                    "
  456. *****************************************************************************
  457. Wiggle
  458.     Pos
  459.     Cmp.w    #$0001,Part+2
  460.     Beq    SetWiggle
  461.     Tst.l    WiggleDel
  462.     Beq    OutOfWig
  463.     Sub.w    #1,WiggleDel
  464.     SaveAll
  465.     Bsr    DoBitmapscop
  466.     LoadAll
  467.     Bsr    CopSin
  468.     Rts
  469. OutOfWig
  470.     Move.w    PartToRn,Part
  471.     Move.w    #$0001,Part+2
  472.     Rts
  473. SetWiggle
  474.     Move.w    #300,WiggleDel
  475.     Lea    CopCrea,A0
  476.     Lea    Copper3,A1
  477. CopLoop2
  478.     Move.l    (a1)+,D0
  479.     Cmp.l    #$fffffffe,D0
  480.     Beq.s    OutOfCop
  481.     Move.l    D0,(a0)+
  482.     Bra    CopLoop2
  483. OutOfCop
  484.     Move.l    #202-1,D7
  485.     Move.l    #$4509fffe,d0
  486. CreatLoop
  487. A    Set    $0182
  488.     Rept    31
  489.     Move.w    #a,(a0)+
  490.     Move.w    #$002,(a0)+
  491. A    Set    A+2
  492.     Endr
  493.     Add.l    #$01000000,D0
  494.     Move.l    d0,(a0)+
  495.     Dbf    D7,CreatLoop
  496.     Move.l    #$1009fffe,(a0)+
  497.     Move.l    #$0180000f,(a0)+
  498.     Move.l    #$01000200,(a0)+
  499.     Move.l    #$1109fffe,(a0)+
  500.     Move.l    #$01800000,(a0)+
  501. A    Set    $0182
  502.     Rept    31
  503.     Move.w    #$002,(a0)+
  504. A    Set    A+2
  505.     Endr
  506.     Move.l    #$fffffffe,(a0)+
  507.     Clr.w    ScrollCop
  508.     Move.l    #$70000,Cop1lch(a5)
  509.     Clr.w    Part+2
  510.     Rts
  511. DoBitmapscop
  512.     Lea    CopCrea,A0
  513.     Lea    Copper3,A1
  514. CopLoop3
  515.     Move.l    (a1)+,D0
  516.     Cmp.l    #$fffffffe,D0
  517.     Beq.s    OutOfCop1
  518.     Move.l    D0,(a0)+
  519.     Bra    CopLoop3
  520. OutOfCop1    
  521.     Cmp.w    #42,WiggleDel
  522.     Blt    RightCops
  523.     Move.l    #Pic1x,D0                ; Init Bitmaps
  524.     Add.l    ScrollCop,D0
  525.     Cmp.l    #44,ScrollCop
  526.     Beq.s    LeaveCopS
  527.     Add.l    #2,ScrollCop
  528. LeaveCopS
  529.     PlaneOn    D0,CopBit1l+2,CopBit1h+2
  530.     Add.l    #88,D0
  531.     PlaneOn    D0,CopBit2l+2,CopBit2h+2
  532.     Add.l    #88,D0
  533.     PlaneOn    D0,CopBit3l+2,CopBit3h+2
  534.     Add.l    #88,D0
  535.     PlaneOn    D0,CopBit4l+2,CopBit4h+2
  536.     Add.l    #88,D0
  537.     PlaneOn    D0,CopBit5l+2,CopBit5h+2
  538.     Rts
  539. RightCops
  540.     Move.l    #Pic1x,D0                ; Init Bitmaps
  541.     Add.l    ScrollCop,D0
  542.     Cmp.l    #0,ScrollCop
  543.     Beq.s    LeaveCopS1
  544.     Sub.l    #2,ScrollCop
  545. LeaveCopS1
  546.     PlaneOn    D0,CopBit1l+2,CopBit1h+2
  547.     Add.l    #88,D0
  548.     PlaneOn    D0,CopBit2l+2,CopBit2h+2
  549.     Add.l    #88,D0
  550.     PlaneOn    D0,CopBit3l+2,CopBit3h+2
  551.     Add.l    #88,D0
  552.     PlaneOn    D0,CopBit4l+2,CopBit4h+2
  553.     Add.l    #88,D0
  554.     PlaneOn    D0,CopBit5l+2,CopBit5h+2
  555.     Rts
  556. *****************************************************************************
  557. WiggleDel
  558.     Dc.l    0
  559. ScrollCop
  560.     Dc.l    0
  561. *****************************************************************************
  562. CopSin
  563.     Move.l    #$09f00000,Bltcon0(a5)
  564.     Move.w    #126,Bltdmod(a5)
  565.     Move.w    #000,Bltamod(a5)
  566.     Move.l    #-1,Bltafwm(a5)
  567.     Move.w    #31-1,D7        ; Number Of Colours
  568.     Move.l    #CopCrea+$5A,D2
  569.     Move.w    #202*64+1,D3
  570.     Lea    Form1,A0
  571.     Lea    Sin1,A1
  572.     Move.w    #2,D4
  573.     Move.w    #$1fe,d5
  574. CopLoop
  575.     Move.l    (a0)+,D0
  576.     Move.w    (a0),d1
  577.     Add.w    d4,(a0)
  578.     And.w    d5,(a0)+
  579.     Add.w    (a1,d1),d0
  580.     Move.l    D0,Bltapth(a5)
  581.     Move.l    D2,Bltdpth(a5)
  582.     Move.w    D3,Bltsize(a5)
  583.     Add.w    #4,D2
  584.     Dbf    D7,CopLoop
  585.     Rts
  586. *****************************************************************************
  587. ColPat1
  588.     Rept    7
  589.     Dc.w    $fff,$eff,$dff,$cff,$bff,$aff,$9ff,$8ff
  590.     Dc.w    $7ff,$6ff,$5ff,$4ff,$3ff,$2ff,$1ff,$0ff
  591.     Dc.w    $1fe,$2fd,$3fc,$4fb,$5fa,$6f9,$7f8,$8f7
  592.     Dc.w    $9f6,$af5,$bf4,$cf3,$df2,$ef1,$ff0,$fe1
  593.     Dc.w    $fd2,$fc3,$fb4,$fa5,$f96,$f87,$f78,$f69
  594.     Dc.w    $f5a,$f4b,$f3c,$f2d,$f1e,$f0f,$f1f,$f2f
  595.     Dc.w    $f3f,$f4f,$f5f,$f6f,$f7f,$f8f,$f9f,$faf
  596.     Dc.w    $fbf,$fcf,$fdf,$fef
  597.     Endr
  598.     
  599. *****************************************************************************
  600. Form1
  601. A    Set    0
  602.     Rept    31
  603.     Dc.l    ColPat1
  604.     Dc.w    (A&$1fe)
  605. A    Set    a+4
  606.     Endr
  607. *****************************************************************************
  608. Sin1    
  609.     Include    Demo/Sintab2
  610.     Include    Demo/Sintab2
  611. *****************************************************************************
  612. Pic1x    Incbin    Gfx/Wig1.bm
  613. *****************************************************************************
  614. Copper1
  615.     Spr_Off                        ; Switch sprites off
  616.     Cmove    $2c81,Diwstrt
  617.     Cmove    $2cc1,Diwstop
  618.     Cmove    $0038,Ddfstrt
  619.     Cmove    $00d0,Ddfstop
  620.     Cmove    $0078,Bpl1mod            
  621.     Cmove    $0078,Bpl2mod
  622.     dc.w    $0180,$0000,$0182,$0fff,$0184,$0ddd,$0186,$0ccc
  623.     dc.w    $0188,$0bbb,$018a,$0999,$018c,$0888,$018e,$0666
  624.     dc.w    $0190,$0555,$0192,$0333,$0194,$0222,$0196,$0540
  625.     dc.w    $0198,$0750,$019a,$0960,$019c,$0b70,$019e,$0d90
  626.     Cwait    68,0
  627.     Cmove    $000f,Color00                ; Col Of Top Line
  628.     Cwait    69,0
  629.     Cmove    $0002,Color00                ; Page Col
  630.     Cwait    71,0
  631.     Cmove    $0007,Bpl1pth
  632. Cop1l    Cmove    $0000,Bpl1ptl
  633.     Cmove    $0007,Bpl2pth
  634. Cop2l    Cmove    $0028,Bpl2ptl
  635.     Cmove    $0007,Bpl3pth
  636. Cop3l    Cmove    $0050,Bpl3ptl
  637.     Cmove    $0007,Bpl4pth
  638. Cop4l    Cmove    $0078,Bpl4ptl
  639.     Cmove    $4200,Bplcon0
  640. BobCopStart
  641.     Dcb.b    8820
  642. CopEnd
  643.     EndCop
  644. *****************************************************************************
  645. Copper2
  646.     Cmove    $2881,Diwstrt
  647.     Cmove    $2cc1,Diwstop
  648.     Cmove    $0038,Ddfstrt
  649.     Cmove    $00d0,Ddfstop
  650.     Cmove    $0002,Bplcon1
  651.     Cmove    $0000,Bpl1mod            
  652.     Cmove    $0000,Bpl2mod
  653.     Cmove    $0000,Color00
  654. FadeDis
  655.     Cmove    $0ddf,Color02
  656.     Cmove    $0446,Color01
  657.     Cmove    $088a,Color03
  658.     Cwait    68,0
  659.     Cmove    $000f,Color00                ; Col Of Top Line
  660.     Cwait    69,0
  661.     Cmove    $0002,Color00                ; Page Col
  662.     Cwait    72,0
  663.     Cmove    $3000,Bpl1ptl
  664.     Cmove    $0007,Bpl1pth
  665.     Cmove    $3028,Bpl2ptl
  666.     Cmove    $0007,Bpl2pth
  667.     Cmove    $2200,Bplcon0
  668.     Pal
  669.     Cwait    16,0
  670.     Cmove    $000f,Color00
  671.     Cmove    $0200,Bplcon0
  672.     Cwait    17,0
  673.     Cmove    $0000,Color00
  674.     EndCop
  675. *****************************************************************************
  676. Copper3
  677.     Cmove    $2871,Diwstrt
  678.     Cmove    $2cd1,Diwstop
  679.     Cmove    $0028,Ddfstrt
  680.     Cmove    $00d0,Ddfstop
  681.     Cmove    $00bb,Bplcon1
  682.     Cmove    -44,Bpl1mod            
  683.     Cmove    -44,Bpl2mod
  684. CopBit1l Cmove    $0000,Bpl1ptl
  685. CopBit1h Cmove    $0000,Bpl1pth
  686. CopBit2l Cmove    $0000,Bpl2ptl
  687. CopBit2h Cmove    $0000,Bpl2pth
  688. CopBit3l Cmove    $0000,Bpl3ptl
  689. CopBit3h Cmove    $0000,Bpl3pth
  690. CopBit4l Cmove    $0000,Bpl4ptl
  691. CopBit4h Cmove    $0000,Bpl4pth
  692. CopBit5l Cmove    $0000,Bpl5ptl
  693. CopBit5h Cmove    $0000,Bpl5pth
  694.     Cwait    68,0
  695.     Cmove    $000f,Color00                ; Col Of Top Line
  696.     Cwait    69,0
  697.     Cmove    $0002,Color00                ; Page Col
  698.     Cmove    $5200,Bplcon0
  699.     EndCop
  700. *****************************************************************************
  701. BobForm1
  702.     Dc.w    4,2                    ; Xupdate, Yupdate
  703.     Dc.w    000,000                    ; X,Y
  704.     Dc.w    050,050                    ; X,Y
  705.     Dc.w    100,100                    ; X,Y
  706.     Dc.w    150,150                    ; X,Y
  707.     Dc.w    200,200                    ; X,Y
  708. *****************************************************************************
  709.     Include    Demo/SinTab1
  710. *****************************************************************************
  711. Bobs    Incbin    Gfx/BigBobs.Bm
  712. BobsMsk    Incbin    Gfx/BigBobsMsk.Bm
  713. *****************************************************************************
  714. ScreenPtr
  715.     dc.l    $70000
  716. *****************************************************************************
  717. Font
  718.     Incbin    Gfx/16x16.bm
  719. *****************************************************************************
  720. XPos    Dc.l    0
  721. YPos    Dc.l    0
  722. Apear1
  723.     Incbin    Gfx/ApearText1
  724.     Incbin    Gfx/ApearText1
  725. *****************************************************************************
  726.                
  727.